//Import TweenMax
import gs.*;
 
/*
Vanishing point for the y coordinate.
So when the object is really far away, the y coordinate is almost equal to the vanishing point.
*/
var vanishingPointY:Number = stage.stageHeight / 2;
 
//Focal length determines how much perspective is seen.
var focalLength:Number = 300;
 
//This array will hold all our circles and the text
var itemsArray:Array = new Array();
 
//Add our text to the array
itemsArray.push(myText);
 
//Add our circle to the array
itemsArray.push(myCircle);
 
//Angle speed for the circle
var angleSpeed:Number = 0.2;
 
//Horizontal speed for the circle
var xSpeed:Number = 4;
 
//The y radius (height) of our "tunnel" is determined by the text height
var yRadius:Number = myText.height;
 
//The z radius (depth) is calculated from the yRadius
var zRadius:Number = yRadius * 3;
 
//Assign an initial 3D y and z coordinate
myCircle.ypos3D = 0;
myCircle.zpos3D = 0;
 
//Assign a 3D z position for the text so we can animate the circle around it
myText.zpos3D = 0;
 
//Initial angle for the circle
myCircle.currentAngle = 0;
 
//Add an ENTER_FRAME listener so we can animate the circle
myCircle.addEventListener(Event.ENTER_FRAME, moveCircle);
 
/*
We start a timer at the beginning of the movie.
In each timer event, we will create a new trail circle.
*/
var timer:Timer = new Timer(20,0);
timer.addEventListener(TimerEvent.TIMER, createTrail);
timer.start();
 
//This function moves the circle ("myCircle" instance)
function moveCircle(e:Event):void {
 
	//Update the circle's angle
	myCircle.currentAngle += angleSpeed;
 
	//Calculate the new 3D y position
	myCircle.ypos3D=Math.sin(myCircle.currentAngle)*yRadius;
 
	//Calculate the new 3D z position
	myCircle.zpos3D=Math.cos(myCircle.currentAngle)*zRadius;
 
	//Calculate a scale ratio
	var scaleRatio = focalLength/(focalLength + myCircle.zpos3D);
 
	//Scale the circle according to the ratio
	myCircle.scaleX=myCircle.scaleY=scaleRatio;
 
	//Update the x coordinate
	myCircle.x+=xSpeed;
 
	//Update the y coordinate
	myCircle.y=vanishingPointY+myCircle.ypos3D*scaleRatio;
 
	//If the circle is over the right side, move it to the left
	if (myCircle.x>stage.stageWidth+20) {
		myCircle.x=-20;
	}
 
	//Call the function that sorts the circles so they overlap correctly
	sortZ();
}
 
//This function creates a new trail circle
function createTrail(e:Event):void {
 
	//Create a new circle
	var newCircle:MyCircle = new MyCircle();
 
	//Assign the same z position as the "myCircle" has
	newCircle.zpos3D=myCircle.zpos3D;
 
	//Assign the same coordinates
	newCircle.x=myCircle.x;
	newCircle.y=myCircle.y;
 
	//Calculate the scale ratio
	var scaleRatio = focalLength/(focalLength + newCircle.zpos3D);
 
	//Scale the circle according to the ratio
	newCircle.scaleX=newCircle.scaleY=scaleRatio;
 
	//Push the circle to the the items array
	itemsArray.push(newCircle);
 
	//Add the circle to the stage
	addChild(newCircle);
 
	//Call the sorting so the new circle overlaps correctly
	sortZ();
 
	/*
	Use TweenMax to scale down the circle.
	We call the function removeCircle when the tween is finished.
	*/
	TweenMax.to(newCircle, 2, {alpha: 0, scaleX:0, scaleY:0, onComplete: removeCircle, onCompleteParams: [newCircle]});
}
 
//This function is called when a circle tween is finished
function removeCircle(circle:MyCircle):void {
 
	//Remove the circle from the array
	var i:uint=itemsArray.indexOf(circle);
	itemsArray.splice(i, 1);
 
	//Remove the circle from the stage
	removeChild(circle);
}
 
//This function sorts the circles so they overlap each others correctly
function sortZ():void {
 
	/*
	Sort the array so that the circle which has the highest 
	z position (= furthest away) is first in the array.
	*/
	itemsArray.sortOn("zpos3D", Array.NUMERIC | Array.DESCENDING);
 
	//Set new child indexes for the items
	for (var i:uint = 0; i < itemsArray.length; i++) {
		setChildIndex(itemsArray[i], i);
	}
}