//We use a timer to create the rectangles when the mouse is over the text.
//This timer will send an event every 0.02 seconds.
var timer:Timer = new Timer(20, 0);
timer.addEventListener(TimerEvent.TIMER, createRectangle);
 
//We want to know wheter the mouse is over the text or not
var mouseOverText:Boolean = false;
 
//Make the text look like a button (hand cursor appears on mouse hover)
myText.buttonMode = true;
 
//Listen when the mouse is over the text
myText.addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
 
//Listen when the mouse moves out from the text
myText.addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
 
//This function is called when the mouse is over the text
function mouseOverHandler(e:Event):void {
 
	//Start the timer
	timer.start();
}
 
//This function is called when the mouse moves out from the text
function mouseOutHandler(e:Event):void {
 
	//Reset the timer
	timer.reset();
}
 
//This function is called every 0.02 seconds when the timer is running
function createRectangle(e:Event):void {
 
	//Create a new rectangle
	var rectangle:MyRectangle = new MyRectangle();
 
	//Assign a random x position to the rectangle
	rectangle.x = myText.x + Math.random() * myText.width;
 
	//Assign the y position to the rectangle
	rectangle.y = myText.y + myText.height / 2;
 
	//Assign a random scale for the rectangle
	rectangle.scaleX = rectangle.scaleY = Math.random() * 2;
 
	//Assign a random x and y speed for the rectangle
	rectangle.xspeed = Math.random() * 10 - 5;
	rectangle.yspeed = Math.random() * 10 - 5;
 
	//Assign a random alpha speed (how fast the rectangle disappears)
	rectangle.alphaSpeed = -(Math.random() * 0.1);
 
	//Assign a random scale speed
	rectangle.scaleSpeed = Math.random() * 0.05;
 
	//Assign a random color for the rectangle
	var colorInfo:ColorTransform = rectangle.transform.colorTransform;
	colorInfo.color = 0xffffff * Math.random();
	rectangle.transform.colorTransform = colorInfo;
 
	//We don't want to catch any mouse events from the rectangle
	rectangle.mouseEnabled = false;
 
	//Add ENTER_FRAME listener for the rectangle
	rectangle.addEventListener(Event.ENTER_FRAME, animate);
 
	//Add the rectangle to the stage.
	//We add it to index zero because we want the rectangle to stay behind the text.
	addChildAt(rectangle,0);
}
 
//This function is called in each frame
function animate(e:Event):void {
 
	//Save the rectangle to a local variable
	var rectangle:MyRectangle = (MyRectangle)(e.target);
 
	//Update its position
	rectangle.x += rectangle.xspeed;
	rectangle.y += rectangle.yspeed;
 
	//Update the alpha
	rectangle.alpha += rectangle.alphaSpeed;
 
	//Update the scale
	rectangle.scaleX += rectangle.scaleSpeed;
	rectangle.scaleY += rectangle.scaleSpeed;
 
	//Assign a random rotation for the rectangle
	rectangle.rotation = Math.random() * 256;
 
	//Remove the rectangle from the stage if alpha is below 0
	if(rectangle.alpha < 0) {
		rectangle.removeEventListener(Event.ENTER_FRAME, animate);
		removeChild(rectangle);
	}
}